scad/catear_headband.scad

include <globals.scad>;

use <headband.scad>;
use <chamfer.scad>;

module catear(height, thickness, fractal=0, side_len=30, bend_factor=0.5, stretch_factor=1.2, debug=false, chamfer=CHAMFER, chamfer_shape=CHAMFER_SHAPE, details=true) {
  $A=[0, side_len/2];
  $B=[0,-side_len/2];
  $C=[-(side_len/2/sin(120))*1.5*stretch_factor, 0];
  $c=sqrt(pow($A.x-$B.x, 2)+pow($A.y-$B.y, 2));
  $b=sqrt(pow($A.x-$C.x, 2)+pow($A.y-$C.y, 2));
  $a=sqrt(pow($C.x-$B.x, 2)+pow($C.y-$B.y, 2));
  $hc=-$C.x;
  $alpha=asin($hc/$b);
  $beta=$alpha;
  $gamma=180-$alpha-$beta;
  $delta=180*bend_factor;
  $bend_radius=$a/(2*cos(90-$delta/2));
  $bend_offset=$bend_radius*sin(90-$delta/2);

  translate([0, -$c/2, 0])
    rotate($beta, [0, 0, 1])
      translate([0, $a/2, 0])
        translate([$bend_offset, 0, 0])
          color("#00ffff")
            chamfer(size=(details)?chamfer:0, child_h=height, child_bot=-height/2, shape=chamfer_shape)
              partial_ring(
                part=$delta/360,
                radius=$bend_radius,
                thickness=thickness,
                height=height
              );
  translate([0, $c/2, 0])
    rotate(-$alpha, [0, 0, 1])
      translate([0, -$b/2, 0])
        translate([$bend_offset, 0, 0])
          color("#ff00ff")
            chamfer(size=(details)?chamfer:0, child_h=height, child_bot=-height/2, shape=chamfer_shape)
              partial_ring(
                part=$delta/360,
                radius=$bend_radius,
                thickness=thickness,
                height=height
              );
  translate($A) color("#aaaaaa")
    chamfer(size=chamfer, child_h=height, child_bot=-height/2, shape=chamfer_shape)
      cylinder(h=height, d=thickness, center=true);
  translate($B) color("#bbbbbb")
    chamfer(size=chamfer, child_h=height, child_bot=-height/2, shape=chamfer_shape)
      cylinder(h=height, d=thickness, center=true);
  translate($C) color("#cccccc")
    chamfer(size=chamfer, child_h=height, child_bot=-height/2, shape=chamfer_shape)
      cylinder(h=height, d=thickness, center=true);

  if (debug) {
    echo("A", $A, "a", $a, "alpha", $alpha);
    echo("B", $B, "b", $b, "beta ", $beta);
    echo("C", $C, "c", $c, "gamma", $gamma);
    echo("bend_factor", bend_factor);
    echo("delta:", $delta);
    echo("bend_radius", $bend_radius);
    echo("bend_offset", $bend_offset);
    color("#000000") cylinder(h=4, d=4);
    translate($C/2) color("red") cube([$hc, thickness, height*1.1], center=true);
    color("red") cube([thickness, $c, height*1.1], center=true);
    color("red") translate([0, $c/2, 0])
      rotate(-$alpha, [0, 0, 1])
        translate([0, -$b/2, 0])
          cube([thickness,$b, height*1.1], center=true);
    color("red") translate([0, -$c/2, 0])
      rotate($beta, [0, 0, 1])
        translate([0, $a/2, 0])
          cube([thickness, $a, height*1.1], center=true);
  }
}

module catear_headband(debug=DEBUG, size=SIZE, height=HEIGHT, thickness=THICKNESS, part=PART, stretch_len=STRETCH_LEN, tip_len=TIP_LEN, tip_bend=TIP_BEND, ear_scale=1.5, ear_bend_factor=0.15, ear_stretch_factor=1.2, ear_angle=42, chamfer=CHAMFER, chamfer_shape=CHAMFER_SHAPE, with_rake=true, details=true) {

  $a=size/2*ear_scale;
  $delta=2*(acos($a/(size*2))-90);
  ear_offset=size*sin(90-$delta/2);

  union() {
    rotate( ear_angle, [0, 0, 1]) {
      translate([-ear_offset, 0, 0]) catear(
        debug=debug,
        height=height,
        thickness=thickness,
        side_len=size/2*ear_scale,
        bend_factor=ear_bend_factor,
        stretch_factor=ear_stretch_factor,
        chamfer=chamfer,
        chamfer_shape=chamfer_shape,
        details=details
      );
    }
    rotate(-ear_angle, [0, 0, 1]) {
      translate([-ear_offset, 0, 0]) catear(
        debug=false,
        height=height,
        thickness=thickness,
        side_len=size/2*ear_scale,
        bend_factor=ear_bend_factor,
        stretch_factor=ear_stretch_factor,
        chamfer=chamfer,
        chamfer_shape=chamfer_shape,
        details=details
      );
    }
    headband(
      size=size,
      height=height,
      thickness=thickness,
      part=part,
      stretch_len=stretch_len,
      tip_len=tip_len,
      tip_bend=tip_bend,
      with_rake=with_rake,
      details=details
    );
  };
}

catear_headband();