scad/loveboard-cover-r2-cat.scad

/**
 * This requires
 * https://files.printables.com/media/prints/451501/stls/4205518_58958bba-4c36-4995-b4e7-da5abd1ba821/loveboard-cover-r2.stl
 * 
 * to be placed under `./stls/LoveBoard-cover-R2.stl` in order to work
 * but it needs a run in meshlabs uniform fcae orientation filter for
 * openscad to be happy with it
 * 
 * if rendering is missing the ear infill, `Design` > `Flush Caches`
 * may be required.
 */
 
include <headband.scad>
use <catear_headband.scad>

HEIGHT=11;
THICKNESS=1;
SIDE_LEN=20;
BEND_FACTOR=0.15;
STRETCH_FACTOR=1.2;
CHAMFER=0;
CHAMFER_SHAPE="none";
DEBUG=false;

FILL=true;
FILL_HEIGHT_FACTOR=0.9;
FILL_HEIGHT_FALLOFF_STEP=0;
FILL_HEIGHT_FALLOFF_FACTOR=0.98;
FILL_HEIGHT_FALLOFF_EXPONENT_FACTOR=3;
FILL_STEP=0.5;

module loveboard_cover_r2_cat() {
  $fn=90;
  union() {
    difference() {
      union() {
        for (i=[-1,1])
          scale([i, 1, 1]) 
            translate([-23, 23, 5.5])
              rotate(-65) {
                catear(
                  height=HEIGHT,
                  thickness=THICKNESS,
                  side_len=SIDE_LEN,
                  bend_factor=BEND_FACTOR,
                  stretch_factor=STRETCH_FACTOR,
                  debug=DEBUG,
                  chamfer=CHAMFER,
                  chamfer_shape=CHAMFER_SHAPE
                );
                if (FILL) {
                  echo("BEGIN FILL");
                  for (i=[FILL_STEP:FILL_STEP:(SIDE_LEN-FILL_STEP)])
                    color([0, (256-i*8)/256,0]) {
                      fill_height=(
                        HEIGHT * FILL_HEIGHT_FACTOR
                      * pow(FILL_HEIGHT_FALLOFF_FACTOR,
                          (SIDE_LEN-1-i)*FILL_HEIGHT_FALLOFF_EXPONENT_FACTOR)
                      - ((SIDE_LEN-1-i)*FILL_HEIGHT_FALLOFF_STEP)
                      );
                      echo([i, fill_height]);
                      translate([0, 0, (fill_height-HEIGHT)/2])
                      catear(
                        height=fill_height,
                        thickness=THICKNESS,
                        side_len=i,
                        bend_factor=BEND_FACTOR,
                        stretch_factor=STRETCH_FACTOR,
                        chamfer=0,
                        chamfer_shape=CHAMFER_SHAPE
                      );
                    }
                  echo("END FILL");
                }
              }
      }
      scale(0.9999) hull() import("stls/LoveBoard-cover-R2.stl");
    }
    color("red") import("stls/LoveBoard-cover-R2.stl");
  }
}

loveboard_cover_r2_cat();